Sub buildAllMethodsNamesInterfaces()
Dim info1 As Variant, info2 As Object
Dim s As String, x As Long, xMax As Long

allMethodsNamesInterfaces = ""
info1 = introCurrObj.getMethods(com.sun.star.beans.MethodConcept.ALL)
xMax = UBound(info1)
if xMax < 0  then  Exit Sub
for x = 0 to xMax ' get info of each method accessible from the object
  info2 = info1(x)
  s = "£" & info2.Name & "£" & info2.DeclaringClass.Name & "£"
  if InStr(1, allMethodsNamesInterfaces, s, 0) = 0  then ' new name+interface
    allMethodsNamesInterfaces = allMethodsNamesInterfaces & s
  end if
next
End Sub

'  Note :  arg newObj is mandatory ! Optional only to handle error case VarType = 10
Sub checkAndDisplayNewObject(Optional newObj As Variant, ObjPath As String) As Boolean
if isWorthXray(newObj)  then
  if EqualUnoObjects(newObj, CurrentObj)  then
    MsgBox(txt0109, 0, WindowTitle) ' this is the same object
  elseif initXrayDisplay(newObj, ObjPath, true) then
    ' OK, ObjPath will be added to listbox ListObj
  end if
end if
End Sub

' INOUT parameter : array s()
Sub explainAttribute(propName As String, propKind As Long, s As Variant)
Dim t As String, t2 As String, n As Long

t = s(F3notes)
n = propKind H00010000000 ' get the attributes of the attribute
' see bottom of page http://wiki.services.openoffice.org/wiki/Documentation/DevGuide/ProUNO/Properties
s(F3attribProp) = txt0341
' currently, an attribute can't be REMOVEABLE
t2 = findInterfaceOfAttribute(propName)
if Len(t2) > 0  then
  t = t & LF & txt0342 & t2
else
  Select Case isAlternateDoc(propName, "attribute")
  Case "found"
    t = t & LF & txt0344
  Case "not found"
    t = t & LF & txt0343
  End Select
end if
if (n and com.sun.star.beans.PropertyAttribute.READONLY) <> 0         then  t = t & LF & txt0346
if (n and com.sun.star.beans.PropertyAttribute.MAYBEVOID) <> 0        then  t = t & LF & txt0230
if showAll  then
  if (n and com.sun.star.beans.PropertyAttribute.MAYBEAMBIGUOUS) <> 0 then  t = t & LF & txt0234
  if (n and com.sun.star.beans.PropertyAttribute.MAYBEDEFAULT) <> 0   then  t = t & LF & txt0348
  if (n and com.sun.star.beans.PropertyAttribute.BOUND) <> 0          then  t = t & LF & txt0231
  if (n and com.sun.star.beans.PropertyAttribute.CONSTRAINED) <> 0    then  t = t & LF & txt0232
  if (n and com.sun.star.beans.PropertyAttribute.TRANSIENT) <> 0      then  t = t & LF & txt0347
end if

s(F3notes) = t
End Sub

' INOUT parameter : array s()
Sub explainPseudoPropertyCaracteristics(propName As String, propKind As Long, s As Variant)
Dim t As String, w As String, intfGet As String, intfSet As String

t = s(F3notes)
intfGet = "none"
intfSet = "none"
if (propKind and &H00000001) <> 0  then ' prop is a getter
  s(F3get) = txt0219 & "get" & propName & "( ) "
  if (propKind and &H00000002) <> 0  then ' getter is ambiguous
    t = t & LF & replaceTag(txt0243, "getXxx", "get" & propName & "( ) ") ' name conflict, use getXxx from appropriate interface
    s(F3important) = txt0229 ' name conflict : see notes
    s(F3canXray) = "noXray"
  else
    intfGet = getPseudoPropInterface("get", propName) ' should return the interface name, not "none" or "several" !
    if (propKind and &H00000004) = 0  then t = t & LF & txt0223 ' no setXxx : pseudo-property can only be read
  end if
end if

if (propKind and &H00000004) <> 0  then ' prop is a setter
  s(F3set) = txt0219 & "set" & propName & "(" & txt0242 & ") "
  if (propKind and &H00000008) <> 0  then ' setter is ambiguous
    t = t & LF & replaceTag(txt0244, "setXxx", "set" & propName & "( ) ") ' name conflict, use setXxx from appropriate interface
    s(F3important) = txt0229 ' name conflict : see notes
  else
    intfSet = getPseudoPropInterface("set", propName) ' should return the interface name, not "none" or "several" !
    if (propKind and &H00000001) = 0  then ' no getXxxx
      t = t & LF & txt0222 ' pseudo-property can only be written
      s(F3canXray) = "noXray"
    end if
  end if
end if

if intfGet <> "none"  then
  if intfSet <> "none"  then
    if intfGet = intfSet  then
      t = t & LF & txt0253 & intfGet ' interface : ...
    else ' getXxx and setXxx have different interfaces ! use methods instead of pseudo-prop
      w = replaceTag(txt0245, "getXxx", "get" & propName & "( ) ")
      w = replaceTag(w,       "setXxx", "set" & propName & "( ) ")
      t = t & LF & w
    end if
  elseif (propKind and &H0000000A) = 0  then ' only getXxx, no ambiguity
    t = t & LF & txt0252 & intfGet ' interface : ...
  end if
else
  if (intfSet <> "none") and ((propKind and &H0000000A) = 0)  then ' only setXxx, no ambiguity
    t = t & LF & txt0252 & intfSet ' interface : ...
  end if
end if
s(F3notes) = t
End Sub

' look if this object has already been Xrayed
' returns true if successful
Function foundInXrayList(newObjName As String) As Boolean
Dim kt As Object, y1 As Integer

kt = XrDial.getControl("ListObj")
for y1 = 0 to kt.ItemCount -1
  if newObjName = kt.getItem(y1)  then
    kt.selectItemPos(y1, true) ' do as if user had selected this position
    XrayBack
    foundInXrayList = true
    exit function
  end if
next
foundInXrayList = false
End Function

' parameter getset is "get" or "set"
' returns the name of the interface that qualifies as getter or setter
'   or "several" if more than one interface satisfies
'   or "none" if no interface satisfies
Function getPseudoPropInterface(getset As String, propName As String) As String
Dim methName As String, interfName As String, result As String
Dim info1 As Object, x As Long, y As Long, isGetterSetter As Boolean

result = "none"
methName = getset & propName
x = InStr(1, allMethodsNamesInterfaces, "£" & methName & "£", 0)
Do While x > 0 ' a method of this name exists
  x = x +Len(methName) +2
  y = InStr(x, allMethodsNamesInterfaces, "£", 0)
  interfName = MidP1P2(allMethodsNamesInterfaces, x, y-1)
  info1 = introCurrObj.getMethod(join(split(interfName, "."), "_") & "_" & methName, com.sun.star.beans.MethodConcept.ALL)
  if getset = "get"  then
    isGetterSetter = (UBound(info1.ParameterInfos) < 0) and (info1.ReturnType.Name <> "void")
  else ' "set"
    isGetterSetter = (UBound(info1.ParameterInfos) = 0) and (info1.ReturnType.Name = "void")
  end if
  if isGetterSetter then
    if result = "none"  then
      result = interfName  
    else
      result = "several"
      Exit Do ' ambiguous name : more than one interface provides a getter or setter
    end if
  end if
  x = InStr(y+1, allMethodsNamesInterfaces, "£" & methName & "£", 0) ' search another method of same name
Loop
getPseudoPropInterface = result
End Function

' OUT parameters : v, vError
Sub getValueOfProperty(propName As String, propReadable As Long, propKind As Long, v As Variant, vError As String)

if propReadable > notReadable  then
  if (propKind and &H00000600) <> 0  then ' attribute or real property
    vError = ""
  elseif (propKind and &H00000003) = &H00000001  then ' pseudo-property getXxxx non ambiguous
    if propReadable = arrayProp  then  vError = checkHugeArray(propName)  else vError = ""
  elseif (propKind and &H00000003) = &H00000003  then ' ambiguous getXxx
    vError = "ambiguous" ' ambiguous in the context of obtaining a value, ambiguous setXxx is not looked here
  else ' pseudo-property setXxxx exists but not getXxxx
    vError = "not readable"
  end if
else
  vError = "not readable"
end if 

if Len(vError) = 0  then
  on Error Goto nogetValue
  v = invocCurrObj.getValue(propName)
  on Error Goto 0
  if not IsArray(v)  then
    if propReadable = dataIsAny  then propReadable = BasicTypeIsPropReadable(VarType(v)) ' update according to obtained data type
  end if
  vError = preliminaryDataControl(v)
end if 
Exit Sub

nogetValue: ' error in the UNO object
  vError = txt0224 & LF & error
  Resume nogetValue1
nogetValue1:
  on Error Goto 0
End Sub

Function interfacesString() As String
Dim foundInterfaces As String, intfName As String
Dim allMainInterfaces As Variant, v As Variant
Dim x As Long, y As Long

allMainInterfaces = Array()
On Error Resume Next ' some bizarre UNO objects don't have getTypes(), example : controlObject.ImageProducer
allMainInterfaces = CurrentObj.getTypes()
On Error GoTo 0
foundInterfaces = LF ' collector of interface names
if UBound(allMainInterfaces) >= 0  then
  for x = 0 to UBound(allMainInterfaces)
    intfName = allMainInterfaces(x).Name
    exploreInterfacesOfInterface(intfName, foundInterfaces) ' recursive search
  next
else ' as an alternative, use interfaces of methods
  if Len(allMethodsNamesInterfaces) > 0  then ' allMethodsNamesInterfaces contains : £name1£interface1££name2£interface2££nameN£interfaceN£
    allMainInterfaces = split(deleteTrail(allMethodsNamesInterfaces, "£"), "££") ' one array element per name+interface
    for x = 0 to UBound(allMainInterfaces)
      y = InStr(2, allMainInterfaces(x), "£", 0) ' search second £
      intfName = Mid(allMainInterfaces(x), y+1) ' keep only the interface name
      exploreInterfacesOfInterface(intfName, foundInterfaces) ' recursive search
    next
  else
    ' no GetTypes() and no methods !
  end if
end if

if Len(foundInterfaces) > 1  then
  foundInterfaces = Mid(foundInterfaces, 2, Len(foundInterfaces) -2) ' strip LF at start and end
  v = split(foundInterfaces, LF)
  ShellSort( v() )
  interfacesString = join(v(), " " & LF)
else
  interfacesString = " " & LF & txt0116 ' this object has no interfaces !
end if
End Function

Function methodsString(ordering As String) As String
Dim info1 As Variant, info2 As Object, info3 As Variant, paramModes As Variant
Dim infoParam As Object, methodsArray As Variant
Dim  methInf As String, methodx As String, methRetx As String, methodsList As String
Dim x As Long, xMax As Long, y As Long

paramModes = Array("", "OUT! ", "IN/OUT! ")
info1 = introCurrObj.getMethods(com.sun.star.beans.MethodConcept.ALL)
xMax = UBound(info1)
if xMax < 0  then
  methodsString = " " & LF & txt0116
  Exit Function
end if
methodsList = LF
for x = 0 to xMax ' get info of each method accessible from the object
  info2 = info1(x)
  methodx = info2.Name ' search if this name appears more than once in allMethodsNamesInterfaces
  y = InStr(1, allMethodsNamesInterfaces, "£" & methodx & "£", 0) ' appears once
  if InStr(y +Len(methodx) +2, allMethodsNamesInterfaces, "£" & methodx & "£", 0) > 0  then methodx = methodx & ambiguousMethodFlag
  spaceTo(methodx, methArgsPos, 1) ' add spaces at right
  info3 = info2.ParameterInfos
  methInf = ""
  for y = 0 to UBound(info3)
    infoParam = info3(y)
    methInf = methInf & paramModes(infoParam.aMode) & infoParam.aName & " as " & getShortTypeStr(infoParam.aType) & ", "
  next
  methodx = methodx & "( " & deleteTrail(methInf, ", ") & " )"
  methRetx = getShortTypeStr(info2.ReturnType)
  if methRetx <> "void"  then
    spaceTo(methodx, methReturnPos, 1) ' add spaces at right
    methodx = methodx & "AS " & methRetx
  end if
  spaceTo(methodx, methInterfPos, 2) ' add spaces at right
  methodx = methodx & info2.DeclaringClass.Name & " "
  if InStr(1, methodsList, LF & methodx & LF, 0) = 0  then methodsList = methodsList & methodx & LF ' avoid duplicated methods
next
methodsList = Mid(methodsList, 2, Len(methodsList) -2) ' suppress LF from both ends
if ordering = "AZ" then
  methodsArray = split(methodsList, LF)
  ShellSort( methodsArray() )
  methodsList = join(methodsArray(), LF)
end if
methodsString = methodsList
End Function

Sub prepareXray
Dim kt As Object

OOoReflection = CreateUnoService("com.sun.star.reflection.CoreReflection")
OOoTypeDescr = GetDefaultContext.getByName("/singletons/com.sun.star.reflection.theTypeDescriptionManager")

' TypeClass enumeration ( same structure for arrays below)
'  VOID              CHAR                 BOOLEAN        BYTE      SHORT
'  UNSIGNED_SHORT    LONG                 UNSIGNED_LONG  HYPER     UNSIGNED_HYPER
'  FLOAT             DOUBLE               STRING         TYPE      ANY
'  ENUM              TYPEDEF              STRUCT         UNION     EXCEPTION
'  SEQUENCE          ARRAY                INTERFACE      SERVICE   MODULE
'  INTERFACE_METHOD  INTERFACE_ATTRIBUTE  UNKNOWN        PROPERTY  CONSTANT
'  CONSTANTS         SINGLETON

' converts an API type to the nearest Basic type. Except for char, byte, hyper.
TypeClass2Basic = Array( _
  "void",    "char",   "boolean", "byte",   "integer", _
  "integer", "long",   "long",    "hyper",  "hyper", _
  "single",  "double", "string",  "type",   "variant", _
  "integer", "object", "struct",  "object", "object", _
  "array",   "array",  "object",  "object", "object", _
  "object",  "object", "unknown", "object", "object", _
  "object",  "object")
  

' indicates if a value of a given API type can be read and displayed in the property panel
TypeClassIsPropReadable = Array( _
  notReadable, OKreadable,  OKreadable,  OKreadable,  OKreadable, _
  OKreadable,  OKreadable,  OKreadable,  OKreadable,  OKreadable, _
  OKreadable,  OKreadable,  OKreadable,  notReadable, dataIsAny, _
  OKreadable,  notReadable, noDisplay,   notReadable, notReadable, _
  arrayProp,   arrayProp,   noDisplay,   noDisplay,   noDisplay, _
  notReadable, notReadable, notReadable, notReadable, OKreadable, _
  notReadable, notReadable)

' indicates if the type obtained from an any can be read and displayed in the property panel
' index is VarType(value)
BasicTypeIsPropReadable = Array( _
  OKreadable, OKreadable, OKreadable, OKreadable, OKreadable, OKreadable, OKreadable, OKReadable, _
  OKreadable, noDisplay, notReadable, OKreadable, noDisplay, notReadable, notReadable, notReadable, _
  OKreadable, OKreadable, OKreadable, OKreadable, OKreadable, notReadable, notReadable, notReadable, _
  notReadable, notReadable, notReadable, notReadable, notReadable, notReadable, notReadable, notReadable, _
  notReadable, notReadable, notReadable, OKReadable, notReadable, OKReadable, notReadable, notReadable, _
  notReadable)

pseudoprop = Array("", "(get), read-only, ", "", "(get?), read-only, ", "(set), write-only, ", "(get,set), ", _
  "(set), write-only, ", "(get?,set), ", "", "(get), read-only, ", "", "(get?), read-only, ", "(set?), write-only, ", _
  "(get,set?), ", "(set?), write-only, ", "(get?,set?), " )


LF = chr(10) ' New line, Unix style
emptyLine = LF & " "
initDlgXray ' will create the dialogue and XrDial
End Sub

Function propertiesPanelString(ordering As String) As String
Dim kt As Object
Dim objInternalName As String, typ As String, header As String

if showAll  then
  propValPos = 72     ' right side of value
  propValMinWidth = 20 ' guaranteed minimum width
else
  propValPos = 67
  propValMinWidth = 9
end if
kt = XrDial.getControl("HeaderLabel")
if IsArray(CurrentObj)  then
  typ = deleteTrail( LCase(TypeName(CurrentObj)), "()" ) ' the type name is followed by (), delete them
  objInternalName = txt0201 & typ
  propertiesPanelString = Value2Str(CurrentObj, showFullString +showHexaValue)
  enableControls(XrDial, Array("showAllFlag", "AZflag", "displayWhat", "SDKBtn"), False)
elseif classeIDL.TypeClass = com.sun.star.uno.TypeClass.STRUCT  then
  objInternalName = classeIDL.Name 
  header = " " & txt0409
  spaceTo(header, propTypePos, 1) ' tabulation to "type" column
  header = header & txt0402
  addValueToDisplay(header, txt0403)
  kt.Text = header & txt0404
  propertiesPanelString = structure2String(ordering)
  enableControls(XrDial, Array("displayWhat"), False)
elseif (VarType(CurrentObj) = 9) and not IsNull(introCurrObj) then ' object
  objInternalName = classeIDL.Name 
  header = " " & txt0401
  spaceTo(header, propTypePos, 1) ' tabulation to "type" column
  header = header & txt0402
  addValueToDisplay(header, txt0403)
  kt.Text = header & txt0404
  propertiesPanelString = properties2String(ordering)
else ' simple value ( or Uno simple type data )
  objInternalName = txt0203 & LCase(TypeName(CurrentObj))
  propertiesPanelString = Value2Str(CurrentObj, showFullString +showHexaValue)
  enableControls(XrDial, Array("showAllFlag", "AZflag", "displayWhat", "SDKBtn", "DeeperBtn", "PrettyDisplayBtn"), False)
end if
kt = XrDial.getControl("currentObjName")
kt.Text = objInternalName
End Function

' returns an array of strings filled at indexes :
'   F3name  F3type F3value
Function simplifiedArrayElementString(arrayIndex As String) As Variant
Dim s(F3max) As String, t As Variant
Dim elemVal As Variant, idxList As Variant

t = split(CurrentObjQualifiedName, ".")
s(F3name) = t(UBound(t)) & arrayIndex
idxList = split(MidP1P2(arrayIndex, 2, Len(arrayIndex) -1), ",") ' get each index value
elemVal = getArrayElement(CurrentObj, UBound(idxList) +1, idxList)
s(F3type) = deleteTrail( LCase(TypeName(elemVal)), "()" ) ' the type name is followed by (), delete them
s(F3value) = Value2Str(elemVal, showFullString +showHexaValue)
if VarType(elemVal) = 9  then s(F3value) = LF & LF & txt0114 ' do Xray to display the value
simplifiedArrayElementString = s()
End Function

' returns an array of strings filled at indexes :
'   F3name [F3attribProp] [F3get] [F3set] F3type F3value [F3Color]
'   F3notes F3important F3canXray
Function simplifiedPropertyString(propName As String) As Variant ' simplified : not for the programmer !
Dim s(F3max) As String, t As String, vError As String, t2 As String
Dim propValue As String, propType As String
Dim info1 As Variant, info2 As Object, v As Variant
Dim propKind As Long, propReadable As Long, x As Long

s(F3name) = propName
info2 = introCurrObj.getProperty(propName, com.sun.star.beans.PropertyConcept.ALL)
addShortTypeStr(info2.Type, propType, propReadable)
s(F3type) = propType
propKind = getPropertyCategory(propName, info2.Attributes)
getValueOfProperty(propName, propReadable, propKind, v, vError)

s(F3notes) = "" ' prepare notes
if (propKind and &H00000100) <> 0  then ' pseudo-property
  explainPseudoPropertyCaracteristics(propName, propKind, s)
else
  explainPropertyCaracteristics(propName, propKind, s)
end if
t = s(F3notes)
if Len(vError) = 0  then
  s(F3value) = Value2Str(v, showFullString +showHexaValue)
  if (propType = "any") or (propType = "variant")  then s(F3type) = propType & "  (" & LCase(TypeName(v)) & ")" ' add final type
  t2 = getEnumStringValue(info2.Type, v, "   ")
  if Len(t2) > 0  then
    s(F3value) = s(F3value) & LF & LF & txt0237 & LF & t2 & " "
  else
    t2 = colorComments(propName, v, showFullString)
    if Len(t2) > 0  then
      s(F3value) = s(F3value) & LF & LF & t2 & " "
      s(F3Color) = v
    end if
  end if
  if (propReadable = noDisplay) and (Len(s(F3canXray)) = 0)  then s(F3value) = LF & LF & txt0114 ' Xray deeper to display (object)
elseif vError = "not readable"  then
  if Len(s(F3canXray)) = 0  then s(F3value) = LF & LF & txt0114 ' Xray deeper to display (object)
elseif vError = "ambiguous"  then
  ' name conflict, already treated
elseif InStr(1, vError, txt0224, 0) = 1  then ' read error : vError = txt0224 & LF & error
  s(F3important) = txt0224
  t = t & Mid(vError, Len(txt0224) +1) ' show read error data in notes, starting with LF
elseif InStr(1, vError, txt0125, 0) = 1  then ' huge array : vError = txt0125 & LF & info
  s(F3important) = txt0125
  t = t & Mid(vError, Len(txt0125) +1) ' show further info in notes, starting with LF
else ' error in the UNO object
  s(F3important) = vError ' read error or simple diagnostic
end if

s(F3notes) = Mid(t, 2) ' skip first LF, if any notes
simplifiedPropertyString = s()
End Function

Function structure2String(ordering As String) As String
Dim elemList As Variant, elemX As Object, v As Variant
Dim x As Long, xMax As Long, accMode As Long
Dim structInf As String
Dim elemComment As String, vError As String, elemVal As String
Dim propReadable As Long ' not yet used but necessary for addShortTypeStr

elemList = classeIDL.Fields
xMax = UBound(elemList)
Dim intf2(xMax) As String
for x = 0 to xMax
  elemX = elemList(x)
  structInf = elemX.Name
  spaceTo(structInf, propTypePos, 1) ' tabulation to "type" column
  addShortTypeStr(elemX.Type, structInf, propReadable)
  elemComment = ""
  accMode = elemX.AccessMode
  if accMode = com.sun.star.reflection.FieldAccessMode.WRITEONLY  then
    elemComment = "write-only, "  
  else
    if accMode = com.sun.star.reflection.FieldAccessMode.READONLY  then elemComment = "read-only, " 
    on Error Goto nogetValue
    v = elemX.get(CurrentObj)
    on Error Goto 0
    vError = preliminaryDataControl(v)
  nogetValue2:
    getShortStringFromValueOfProperty(elemX, v, vError, elemVal, elemComment)
    addValueToDisplay(structInf, elemVal)
  end if
  intf2(x) = structInf & deleteTrail(elemComment, ", ") & " " ' add a trailing space to simplify code
next
if ordering = "AZ" then ShellSort(intf2())
structure2String = join(intf2(), LF)
Exit Function

nogetValue: ' error in the UNO object
  vError = txt0224 & LF & error
  Resume nogetValue1
nogetValue1:
  on Error Goto 0
  GoTo nogetValue2
End Function

' called by other routines
Sub XrayDeeper2(currentLine As String, firstWord As String)
Dim v As Variant

firstWord = restoreSpaces(firstWord) ' some user-defined properties have spaces, e.g. Info 1 in document properties
if XrayDisplayWhat = "properties"  then
  if Left(firstWord, 1) = "("  then ' current line is an element of array
    XrayThisArrayElement(firstWord)     ' simple case, understand it first !
  elseif classeIDL.TypeClass = com.sun.star.uno.TypeClass.STRUCT  then
    XrayThisStructureElement(firstWord) ' simple case
  else
    XrayThisProperty(firstWord)         ' complex case
  end if
elseif XrayDisplayWhat = "methods"  then
  if InStr(1, currentLine, firstWord & ambiguousMethodFlag, 0) = 1  then 'ambiguous method
    XrayThisMethod(firstWord, getLastWordOfString(currentLine) )   ' most complex case
  else
    XrayThisMethod(firstWord, "")  ' no need to specify interface, only one method of this name
  end if
end if
FocusOnInfoControl
End Sub

Sub XrayThisMethod(methName As String, interf As String)
Dim fullMethName As String, qp2 As String, paramValue As String, paramType As String, errMess As String
Dim info1 As Object, info2 As Object, params As Variant, newObj As Variant, v As Variant

errMess = checkHugeArray(methName)
if Len(errMess) > 0  then GoTo reportError
if Len(interf) = 0  then
  fullMethName = methName
else
  fullMethName = join(split(interf, "."), "_") & "_" & methName
end if
info1 = introCurrObj.getMethod(fullMethName, com.sun.star.beans.MethodConcept.ALL)
if info1.ReturnType.Name = "void"  then
  MsgBox(txt0117, 64, WindowTitle) ' Xray impossible, method returns nothing
else
  params = info1.ParameterInfos
  Select Case UBound(params)
  Case -1 ' no parameter : Xray possible
    qp2 = CurrentObjQualifiedName & "." & fullMethName & "()"
    if foundInXrayList(qp2)  then  Exit Sub
    On Error Goto doesnotwork1
    newObj = invocCurrObj.invoke(fullMethName, Array(), Array(), Array() )
    On Error Goto 0
    checkAndDisplayNewObject(newObj, qp2)
  Case 0 ' one parameter, check if usable
    info2 = params(0)
    if info2.aMode = com.sun.star.reflection.ParamMode.OUT  then ' no need to enter a parameter value
      qp2 = CurrentObjQualifiedName & "." & fullMethName & "(v)"
      On Error Goto doesnotwork1
      newObj = invocCurrObj.invoke(fullMethName, Array(v), Array(0), Array(v) ) ' v will be filled by the method but will not be used
      On Error Goto 0
      checkAndDisplayNewObject(newObj, qp2)
    else
      paramType = info2.aType.Name
      if InStr(1, acceptedParamTypes, "£" & paramType & "£", 0) = 0  then
        MsgBox(txt0119, 64, WindowTitle) ' Xray impossible, parameter of unacceptable type
      else ' type is supported, ask for parameter value
        paramValue = InputBox(txt0228 & paramType, WindowTitle, "")
        if paramType = "string"  then
          qp2 = CurrentObjQualifiedName & "." & fullMethName & "(""" & paramValue & """)"
        else
          qp2 = CurrentObjQualifiedName & "." & fullMethName & "(" & paramValue & ")"
        end if
        if foundInXrayList(qp2)  then  Exit Sub
        On Error Goto doesnotwork2
        v = CreateUnoValue(paramType, paramValue)
        if info2.aMode = com.sun.star.reflection.ParamMode.INOUT  then
          newObj = invocCurrObj.invoke(fullMethName, Array(v), Array(0), Array(v) )
        else ' com.sun.star.reflection.ParamMode.IN
          newObj = invocCurrObj.invoke(fullMethName, Array(v), Array(), Array() )
        end if
        On Error Goto 0
        checkAndDisplayNewObject(newObj, qp2)
      end if
    end if
  Case Else
    MsgBox(txt0124, 64, WindowTitle) ' Xray impossible, too many parameters
  End Select
end if
Exit Sub

doesnotwork1:
  errMess = txt0108 & LF & LF & Error
  Resume reportError
doesnotwork2:
  errMess = txt0111 & LF & LF & Error ' perhaps incorrect parameter value
  Resume reportError
reportError:
  On Error Goto 0
  MsgBox(errMess, 16, WindowTitle) ' error message
End Sub

Sub XrayThisStructureElement(fieldName As String)
Dim elemX As Object, newObj As Variant
Dim accMode As Long, qp2 As String, errMess As String

elemX = classeIDL.getField(fieldName)
accMode = elemX.AccessMode
if accMode = com.sun.star.reflection.FieldAccessMode.WRITEONLY  then
  MsgBox(txt0120, 64, WindowTitle) ' xray impossible, write-only
else
  qp2 = CurrentObjQualifiedName & "." & fieldName
  if not foundInXrayList(qp2)  then
    On Error Goto doesnotwork
    newObj = elemX.get(CurrentObj)
    On Error Goto 0
    checkAndDisplayNewObject(newObj, qp2)
  end if
end if
Exit Sub

doesnotwork:
  errMess = Error
  Resume doesnotwork1
doesnotwork1:
  On Error Goto 0
  MsgBox(txt0108 & LF & errMess, 64, WindowTitle) ' Xray does not work with this - error message
End Sub

' returns the string without L rightmost characters
Function amputeRight(fullString As String, L As Long) As String
if (L<0) or (L>Len(fullString))  then
 Err = 14 ' exception invalid parameter
end if
amputeRight = Mid(fullString, 1, Len(fullString) - L)
End Function

' Prevent from creating an array that would gobble up the memory, see OpenOffice Bug 35533
' returns an error message or empty string
Function checkHugeArray(firstWord As String) As String
Dim ra As Object, nbrCols As Long, nbrRows As Long, nbrCells As Double, t As String
Const danger = "/Data/DataArray/FormulaArray/getData/getDataArray/getFormulaArray/"

checkHugeArray = ""
if InStr(1, danger, "/" & firstWord & "/", 0) = 0  then Exit Function
On Error GoTo noRangeAddr
ra = CurrentObj.RangeAddress
nbrCols = ra.EndColumn -ra.StartColumn +1
nbrRows = ra.EndRow -ra.StartRow +1
nbrCells = CDbl(nbrCols) * CDbl(nbrRows)
' Xray can display less than 65536 characters, and needs more than 17 characters per element of the array
if nbrCells > 4000.0 then ' too big array (probably the whole sheet)
  t = replaceTag(txt0126, "%%", "" & nbrCols & " x " & nbrRows & " = " & nbrCells)
  checkHugeArray = txt0125 & LF & t
end if
On Error GoTo 0
Exit Function

noRangeAddr: ' same name but not a spreadsheet method/property
Resume Label1
Label1:
On Error GoTo 0
End Function

' if the item contains a color, returns a displayable string
' if showMinimal, returns RGB(r,g,b) only if not (black or no color)
Function colorComments(itemName As String, colorValue As Variant, howToDisplay As Long) As String
Dim t1 As String, t2 As String

t1 = ""
if (InStr(1, itemName, "Color", 0) > 0 ) and (VarType(colorValue) = 3) then ' this is a Color property
  if howToDisplay = showFullString  then
    if colorValue = -1  then ' no color or automatic
      t1 = txt0602
    elseif (colorValue >= 0) and (colorValue <= 16777215)  then
      t1 = txt0603 & Red(colorValue) & space(5) & txt0604 & Green(colorValue) & space(5) & txt0605 & Blue(colorValue)
      t2 = getColorName(colorValue) ' find color name from palette
      if Len(t2) > 0  then t1 = t1 & LF & txt0601 & t2
    end if
  elseif (colorValue > 0) and (colorValue <= 16777215)  then
    t1 = "RGB(" & Red(colorValue) & "," & Green(colorValue) & "," & Blue(colorValue) & ")"
  end if
end if
colorComments = t1
End Function

' if the string terminates with end1, returns the string whithout end1  else return string unchanged
Function deleteTrail(s As String, end1 As String) As String
Dim e As String

e = Right(s, Len(end1))
if e = end1  then
  deleteTrail = Mid(s, 1, Len(s) -Len(end1))
else
  deleteTrail = s
end if
End Function

' recursive search
' INOUT parameter : foundInterfaces (list)
' adds the names of this interface and its ancestors
Sub exploreInterfacesOfInterface(intfName As String, foundInterfaces As String)
Dim x As Long, intf As Object, allBaseInterfaces As Variant

if InStr(1, foundInterfaces, LF & intfName & " " & LF, 0) > 0  then Exit Sub 'interface already explored
intf = OOoReflection.forName(intfName)
if intf.TypeClass = com.sun.star.uno.TypeClass.INTERFACE  then ' getTypes may return other than interfaces...
  foundInterfaces = foundInterfaces & intfName & " " & LF ' add trailing space to simplify code 
  allBaseInterfaces = intf.getSuperClasses() ' base interfaces are interfaces herited by this interface
  for x = 0 to UBound(allBaseInterfaces)
    exploreInterfacesOfInterface(allBaseInterfaces(x).Name, foundInterfaces) ' ... until no more base interfaces
  next
end if
End Sub

' routine triggered by buttons FindFirstBtn and FindNextBtn in DlgFind
Sub FindFirstFindNext(evt As Object)
Dim dlg As Object, k As Object

k = evt.Source
dlg = k.Context
dlg.Model.Tag = k.Model.Name
dlg.endExecute
End Sub

Sub findInText(controlText As Object)
Dim sel As Object, FindDial As Object, k As Object
Dim theText As String, selectedTerm As String, searchTerm As String, button As String
Dim x As Long, startPos As Long

theText = controlText.Text
sel = controlText.Selection
if sel.Min < sel.Max  then
  selectedTerm = MidP1P2(theText, sel.Min +1, sel.Max)
  if InStr(1, LF & searchTexts & LF, LF & selectedTerm & LF, 1) = 0  then
    if Len(searchTexts) > 0  then
        searchTexts = selectedTerm & LF & searchTexts 
      else
        searchTexts = selectedTerm
      end if
    end if 
else
  selectedTerm = ""
end if
if InStr(1, selectedTerm, LF, 0) > 0  then Exit Sub ' ignore search if selection spans several lines
x = -1
Do
  if (Len(selectedTerm) > 0) and (x <> 0)  then
    startPos = sel.Min +Len(selectedTerm) +1
    searchTerm = selectedTerm
  else
    FindDial = createDialogue("DlgFind", txt0265)
    if x = 0  then FindDial.Model.Step = 2  else FindDial.Model.Step = 1
    k = FindDial.getControl("FindComboBox")
    if Len(searchTexts) > 0  then k.Model.StringItemList = split(searchTexts, LF)
    k.Text = searchTerm
    FindDial.execute
    searchTerm = k.Text
    if InStr(1, LF & searchTexts & LF, LF & searchTerm & LF, 1) = 0  then
      if Len(searchTexts) > 0  then
        searchTexts = searchTerm & LF & searchTexts
      else
        searchTexts = searchTerm
      end if
    end if 
    button = FindDial.Model.Tag
    FindDial.dispose
    Select Case button
    Case "FindFirstBtn"
      startPos = 1
    Case "FindNextBtn"
      startPos = sel.Min +2
    Case Else
      Exit Sub
    End Select
  end if
  x = InStr(startPos, theText, searchTerm, 1) ' search case indifferent
Loop Until x > 0
sel.Min = x -1
sel.Max = x +Len(searchTerm) -1
controlText.Selection = sel
End Sub